Questions and Answers

1. If we are in evil normal state <N>, Org speed keys won't work (because most of the printing keys are used for something else, specifically they are bound in evil-normal-state-map),

2. if we are in evil insert state <I> or in evil emacs state <E>, Org speed keys works (because the printing keys are not bound by evil-mode in evil-insert-state-map nor in evil-emacs-state-map).

Org speed keys are not better than evil-mode nor the other way, they are really differents.

Org speed keys

evil-mode

M-x pp-eval-expression RET (current-active-maps)

M-x pp-eval-expression RET (current-active-maps)

First, we can use the built-in command org-babel-goto-named-src-block (bound to C-c C-v g by default).

After calling org-babel-goto-named-src-block with the point on top of the reference <<my-noweb>>:

1. we're asked in the minibuffer to choose a name,

2. we pick the noweb ref my-noweb, press RET,

3. we jump to the source block named my-noweb.

Second possibility, we can define a command that jump to a noweb block definition when we call it with the point on top of a noweb reference without prompting anything in the minibuffer.

Then we can call it directly or better (if it's the behavior we want) we can add this command to the variable org-open-at-point-functions.

And, now in a source block with the point on top of a noweb reference, we can call org-open-at-point (C-c C-o by default) which will call this new command and jump to the noweb block definition at point (instead of running org-babel-open-src-block-result).

Here an implementation of such a command that we call org-goto-noweb.

(require 'org)

(defun org-noweb-ref-p ()
  "Return the noweb reference at point if any.
If not return `nil'."
  (interactive)
  (let* ((context (org-element-context))
         (type (org-element-type context))
         (noweb-ref
          (and (memq type '(inline-src-block src-block))
               (org-in-regexp (org-babel-noweb-wrap)))))
    (when noweb-ref
      (buffer-substring
       (+ (car noweb-ref) (length org-babel-noweb-wrap-start))
       (- (cdr noweb-ref) (length org-babel-noweb-wrap-end))))))

(defun org-goto-noweb ()
  "Go to the noweb ref at point."
  (interactive)
  (when-let ((ref (org-noweb-ref-p)))
    (let ((point (org-babel-find-named-block ref)))
      (if point
          ;; Taken from `org-open-at-point'.
          (progn
            (org-mark-ring-push)
            (goto-char point)
            (org-show-context)
            ;; return non-nil, in order to use it in
            ;; the variable `org-open-at-point-functions'
            'noweb-found)
        (message "source-code block `%s' not found in this buffer" ref)))))

(add-to-list 'org-open-at-point-functions #'org-goto-noweb)

And here the ert test for the command org-goto-noweb:

;; from org-mode: testing/org-test.el
(defmacro org-test-with-temp-text (text &rest body)
  "Run body in a temporary buffer with Org mode as the active
mode holding TEXT.  If the string \"<point>\" appears in TEXT
then remove it and place the point there before running BODY,
otherwise place the point at the beginning of the inserted text."
  (declare (indent 1))
  `(let ((inside-text (if (stringp ,text) ,text (eval ,text)))
         (org-mode-hook nil))
     (with-temp-buffer
       (org-mode)
       (let ((point (string-match "<point>" inside-text)))
         (if point
             (progn
               (insert (replace-match "" nil nil inside-text))
               (goto-char (1+ (match-beginning 0))))
           (insert inside-text)
           (goto-char (point-min))))
       (font-lock-ensure (point-min) (point-max))
       ,@body)))

(ert-deftest org-goto-noweb-test ()
  (should
   (org-test-with-temp-text
       "#+BEGIN_SRC emacs-lisp :noweb yes
<point><<my-noweb>>
(reverse sentence)
#+END_SRC"
     (org-noweb-ref-p)))
  (should-not
   (org-test-with-temp-text
       "#+BEGIN_SRC emacs-lisp :noweb yes
<<my-noweb>>
(reverse sentence)
#+END_SRC"
     (org-noweb-ref-p)))

  ;; source blocks
  (should
   (org-test-with-temp-text
       "#+NAME: my-noweb
#+BEGIN_SRC emacs-lisp
(setq sentence '(foo bar baz))
#+END_SRC

#+BEGIN_SRC emacs-lisp :noweb yes
<point><<my-noweb>>
(reverse sentence)
#+END_SRC"
     (org-goto-noweb)
     (forward-line)
     (looking-at "\(setq")))
  (should-not
   (org-test-with-temp-text
       "#+NAME: my-noweb
#+BEGIN_SRC emacs-lisp
(setq sentence '(foo bar baz))
#+END_SRC

#+BEGIN_SRC emacs-lisp :noweb yes
<<my-noweb>>
(reverse sentence)
#+END_SRC"
     (org-goto-noweb)))

  ;; inline source blocks
  (should
   (org-test-with-temp-text
       "#+NAME: my-noweb
#+BEGIN_SRC emacs-lisp
(setq sentence '(foo bar baz))
#+END_SRC

src_emacs-lisp{<point><<my-noweb>>}"
     (org-goto-noweb)
     (forward-line)
     (looking-at "\(setq"))))